演算子のオーバーロード

演算子のオーバーロードは，ある型において，その型を含むような演算を定義可能です。例えば次のような形をとります。

using Nemerle;
using Nemerle.Utility;

[Record]
public struct Vector2D
{
   public X : double;
   public Y : double;

   public static @-(vector : Vector2D) : Vector2D
   {
      Vector2D(-vector.X, -vector.Y);
   }

   public static @+(v1 : Vector2D, v2 : Vector2D) : Vector2D
   {
      Vector2D(v1.X + v2.X, v1.Y + v2.Y);
   }

   public static @*(scalar : double, vector : Vector2D) : Vector2D
   {
      Vector2D(scalar * vector.X, scalar * vector.Y);
   }

   public static @*(scalar : double, vector : Vector2D) : Vector2D
   {
      Vector2D(scalar * vector.X, scalar * vector.Y);
   }

   public static @^*^(v1 : Vector2D, v2 : Vector2D) : double
   {
      v1.X * v2.X + v1.Y * v2.Y;
   }
}

def v1 = Vector2D(1.0, 2.0);
def v2 = Vector2D(3.0, -1.0);
_ = -v1;  // Vector2D(-1.0, -2.0)
_ = v1 + v2;  // Vector2D(4.0, 1.0)
_ = 1.5 * v2;  // Vector2D(4.5, -1.5)
_ = v1 ^*^ v2;  // 1.0

マクロ

マクロで演算子を定義する場合は，通常のマクロ定義と同じで特別なことはありません。

[assembly: Nemerle.Internal.Operator("", "+-", false, 240, 241)]
macro @+-(e1, e2)
{
   def plus = <[ $e1 + $e2 ]>;
   def minus = <[ $e1 - $e2 ]>;
   <[ ($plus, $minus) ]>;
}

def solve(b, c)  // x^2 + bx + c = 0 の解を求める
{
   def b' = b / 2.0;
   -b' +- System.Math.Sqrt(b' * b' - c);
}
_ = solve(3.0, 2.0);  // (-1, -2)

実装時の注意

演算子のオーバーロードとマクロのいずれの方法を用いて実装するを考えてみます。既存の型に対して演算子を定義するには，オーバーロードは利用できません。必然的にマクロを選択することになります。独自定義の型に対して演算子を定義する場合はどちらを選ぶべきでしょうか。

もし Nemerle 以外の言語との相互運用を考えるのであれば，他の言語からマクロで定義された演算子を利用することはできません。したがってオーバーロードを利用するほかありません。注意すべき点として，言語によっては演算子として使用できる記号が限られています。外部に公開する演算子については特に気を付けましょう。

Nemerle のみで開発する場合，オーバーロードもマクロも利用できます。オーバーロードが単なる実行時の演算しか定義できないのに対し，マクロは += のように代入と評価を同時に行うような複雑な処理も行うことができます。対してオーバーロードは単純な演算しか定義できませんが， private メンバーを直接利用するなど，より型の実装と密接な処理を容易に行うことができます。どちらが良いかは場合によりますが，高度な機能を求めないのであれば，オーバーロードを使った方が無難でしょう。